基於51單片機的簡單交通燈程式

這是一個比較完整的程式。最近實習要做交通燈，

寫了個程式。比較簡單，不過初學者可以參考，呵呵

;*************************************
;file name:  traffic_light.asm
;
;FOUCTION : 實現交通燈的交替控制及特殊情況（如急救車等）通過時實現綠燈，通過外中斷實現
;
;WRITER   :     守望 
;Finish Time： 2010.6.8
;*************************************
       North_South_Red    BIT  P1.0
       North_South_Yellow BIT  P1.1
       North_South_Green BIT  P1.2
       East_West_Red  BIT  P1.3
       East_West_Yellow BIT  P1.4
       East_West_Green  BIT  P1.5

       Scd   EQU  30H ;秒

 

       ORG  0000H
       JMP  START
        ORG  0003H
        JMP  INIT0
        ORG  000BH
         JMP  TIME0

;*************************************
;NAME:  交通燈交替工作控製程序
;
;FOUCTION: 紅綠黃交替點亮： 紅燈亮33秒鐘後綠燈亮27秒，然後閃爍3秒，最後黃燈點亮三秒 ，迴圈
;
;WRITER  :      
;TIME    : 2010.6.8
;*************************************
TIME0:
        MOV    TH0,#30H
        MOV    TL0,#0B0H
        INC    31H
        MOV    A,31H
N:     CJNE   A,#20,EXIT         ;判斷是否到一秒
         MOV    31H,#0

        INC    Scd
         MOV    A,Scd
         CJNE   A,#27,NEXT1  ;判斷綠燈是否到27s
          SETB   F0
          JMP    EXIT

          NEXT1: MOV    A,Scd
          CJNE   A,#30,NEXT2  ;判斷綠燈是否亮30s
          CLR    F0
          MOV    P1,#0EEH
         JMP    EXIT
NEXT2:
        MOV    A,Scd
        CJNE   A,#33,NEXT3
         MOV    P1,#0F3H   ;初始化
NEXT3:
        MOV    A,Scd
        CJNE   A,#60,NEXT4
        SETB   00H
        JMP    EXIT
NEXT4: MOV    A,Scd
        CJNE   A,#63,NEXT5
        CLR    00H
        MOV    P1,#0F5H
        JMP    EXIT
NEXT5:  MOV    A,Scd
        CJNE   A,#66,EXIT
        MOV    P1,#0DEH
        MOV    Scd,#0
EXIT: RETI

;*************************************
;NAME:  外中斷0
;
;FOUCTION: 東西方向出現特殊情況      ?
;  南北紅燈亮，東西綠燈亮，延時10s
;WRITER  :      
;TIME    : 2010.6.8
;*************************************
INIT0:
        PUSH    PSW
        PUSH    ACC
              
        CLR EA
        MOV R2,P1 ;儲存資料
        MOV     P1,#0F6H
        CALL DELLAY10S
        MOV P1,R2 ;恢複
        SETB    EA
       
        POP     ACC
        POP     PSW
 RETI

;*******************主程式初始化部分**************
START:
        MOV   Scd,  #00H
        MOV   31H,  #00H
        MOV   P1,   #0FFH
        CLR   00H
        CLR   F0
        MOV   TMOD, #01H  ;設定定時器1
        MOV   IE,   #83H  ;設定中斷使能  定時器中斷0、外部中斷0和1
        MOV   SP,   #60H
        MOV   TH0,  #30H
        MOV   TL0,  #0B0H
        SETB  TR0

LOOP:
        JNB    F0,N0
        CPL    East_West_Green          ;綠燈閃三秒
        CALL   DELAY500MS
        JMP    N1
N0:
         JNB    00H,N1
         CPL    North_South_Green          ;綠燈閃三秒
         CALL   DELAY500MS
N1:
         JMP   LOOP
;************************************
;Name  :  DELAY
;
;Fouction:  delay 10s
;
;Time  :  2010.06.09
;Writer  :  
;*************************************
DELLAY10S:

        MOV R4,#0BFH
D1:
     MOV R6,#0BDH
D0:
     MOV R5,#89H
     DJNZ R5,$
     DJNZ R6,D0
     DJNZ R4,D1
     NOP
     RET
;************************************
;Name  :  DELAY
;
;Fouction:  delay 10s
;
;Time  :  2010.06.17
;Writer  :  
;*************************************      
DELAY500MS:   ;Delay 0.5s
    MOV 57H,#17H
DL1:
    MOV 56H,#98H
DL0:
    MOV 55H,#46H
    DJNZ 55H,$
    DJNZ 56H,DL0
    DJNZ 57H,DL1
    RET
 END